<%

 '================================================
 '函數(shù)名：GetRemoteData
 '作  用：獲取遠程網(wǎng)頁代碼內(nèi)容,獲取HTTP頁
 '參  數(shù)：url   ----遠程URL
 '語 言：VbScript (ASP)
 '返回值：遠程HTML代碼
 '================================================
 Public Function GetRemoteData(ByVal URL)
  Cset = "GB2312" '設(shè)置遠程網(wǎng)頁的編碼體例
  Dim strHeader
  Dim l
  
  On Error Resume Next
  
  Dim Retrieval
  Dim ObjStream
  Set ObjStream = CreateObject("ADODB.Stream")
  ObjStream.Type = 1
  ObjStream.Mode = 3
  ObjStream.Open
  Set Retrieval = CreateObject("MSXML2.XMLHTTP")
  With Retrieval
   .Open "GET", URL, False
   .setRequestHeader "Referer", URL
   .send
   If .readyState <> 4 Then Exit Function
   If .Status > 300 Then Exit Function
   '--獲取遠程目標(biāo)網(wǎng)頁文件頭
   strHeader = .getResponseHeader("Content-Type")
   strHeader = UCase(strHeader)
   ObjStream.Write (.responseBody)
  End With
  Set Retrieval = Nothing
  
  If Len(strHeader) > 0 Then
   '--獲取目標(biāo)網(wǎng)頁文件編碼
   l = InStrRev(strHeader, "CHARSET=", -1, 1)
   If l > 0 Then
    Cset = Right(strHeader, Len(strHeader) - l - 7)
   Else
    Cset = Cset
   End If
  End If

  ObjStream.Position = 0
  ObjStream.Type = 2
  ObjStream.Charset = Trim(Cset)
  GetRemoteData = ObjStream.ReadText
  ObjStream.Close
  Set ObjStream = Nothing
  Exit Function
 End Function

%>